当前位置: 萬仟网 > IT编程>数据库>Oracle > ORACLE 配置邮件服务器操作示例

ORACLE 配置邮件服务器操作示例

2020年05月14日  | 萬仟网IT编程  | 我要评论

本文实例讲述了oracle 配置邮件服务器操作。分享给大家供大家参考,具体如下:

在oracle sql developer中执行 必须有begin end

1 创建 acl

begin
  dbms_network_acl_admin.create_acl(acl     => 'email.xml',
                   description => 'enables network permissions for the e-mail server',
                   principal  => 'c##esd_monitor', --表示赋予哪个用户 必须大写
                   is_grant  => true,
                   privilege  => 'resolve',
                   start_date => null,
                   end_date  => null);
end;

2 赋予权限

begin
dbms_network_acl_admin.add_privilege(acl    => 'email.xml', --同上xml名称
                     principal => 'c##esd_monitor', --表示赋予哪个用户 必须大写
                     is_grant  => true,
                     privilege => 'connect', --权限名
                     start_date => null,
                     end_date  => null);
end;

3 设置端口

begin
 dbms_network_acl_admin.assign_acl (    -- 该段命令意思是允许访问acl名为utl_sendmail.xml下授权的用户,使用oracle网络访问包,所允许访问的目的主机,及其端口范围。
  acl    => 'email.xml',
  host    => '*'-- ,       -- ip地址或者域名,填写http://localhost:9000/hello与http://localhost:9000/是会报host无效的
                      -- 且建议使用ip地址或者使用域名,若用localhost,当oracle不是安装在本机上的情况下,会出现问题
  -- lower_port => 9000,           -- 允许访问的起始端口号
  -- upper_port => null           -- 允许访问的截止端口号
 );
 end;

4 查询权限设置情况

select acl,
    principal,
    privilege,
    is_grant,
    to_char(start_date, 'dd-mon-yyyy') as start_date,
    to_char(end_date, 'dd-mon-yyyy') as end_date
 from dba_network_acl_privileges;

5 创建邮件发送存储过程

create or replace procedure send_mail(p_recipient varchar2, -- 邮件接收人
           p_subject  varchar2, -- 邮件标题
           p_message  varchar2, -- 邮件正文
           p_type   number -- 1文本 2html
           ) as
  --下面四个变量请根据实际邮件服务器进行赋值
  v_mailhost varchar2(30) := 'smtp.qq.com'; --smtp服务器地址
  v_user   varchar2(30) := '111@qq.com'; --登录smtp服务器的用户名
  v_pass   varchar2(20) := '111'; --登录smtp服务器的密码 授权码
  v_sender  varchar2(50) := '111@qq.com'; --发送者邮箱,一般与 ps_user 对应
  v_conn utl_smtp.connection; --到邮件服务器的连接
  v_msg varchar2(4000); --邮件内容
 begin
  v_conn := utl_smtp.open_connection(v_mailhost, 25);
  utl_smtp.ehlo(v_conn, v_mailhost); --是用 ehlo() 而不是 helo() 函数
  --否则会报:ora-29279: smtp 永久性错误: 503 5.5.2 send hello first.
  utl_smtp.command(v_conn, 'auth login'); -- smtp服务器登录校验
  utl_smtp.command(v_conn,
           utl_raw.cast_to_varchar2(utl_encode.base64_encode(utl_raw.cast_to_raw(v_user))));
  utl_smtp.command(v_conn,
           utl_raw.cast_to_varchar2(utl_encode.base64_encode(utl_raw.cast_to_raw(v_pass))));
  utl_smtp.mail(v_conn, '<' || v_sender || '>'); --设置发件人 注:网上很多资料直接写v_sender,这样写会报ora-29279: smtp 500 error
  utl_smtp.rcpt(v_conn, '<' || p_recipient || '>'); --设置收件人
  utl_smtp.open_data(v_conn); --打开流
  if p_type = 1 then
   -- 创建要发送的邮件内容 注意报头信息和邮件正文之间要空一行
   v_msg := 'date:' || to_char(sysdate, 'dd mon yy hh24:mi:ss') ||
        utl_tcp.crlf || 'from: ' || '<' || v_sender || '>' ||
        utl_tcp.crlf || 'to: ' || '<' || p_recipient || '>' ||
        utl_tcp.crlf || 'subject: ' || p_subject || utl_tcp.crlf ||
        utl_tcp.crlf -- 这前面是报头信息
        || p_message; -- 这个是邮件正文
   utl_smtp.write_raw_data(v_conn, utl_raw.cast_to_raw(v_msg)); --这样写标题和内容都能用中文
  elsif p_type = 2 then
   utl_smtp.write_data(v_conn,
             'from:' || '<' || v_sender || '>' || utl_tcp.crlf);
   utl_smtp.write_data(v_conn,
             'to:' || '<' || p_recipient || '>' ||
             utl_tcp.crlf);
   utl_smtp.write_raw_data(v_conn,
               utl_raw.cast_to_raw(convert('subject:' ||
                             p_subject ||
                             utl_tcp.crlf,
                             'zhs16gbk')));
   utl_smtp.write_raw_data(v_conn,
               utl_raw.cast_to_raw(convert('content-type:text/html;charset=gbk' ||
                             utl_tcp.crlf,
                             'zhs16gbk')));
   utl_smtp.write_data(v_conn, utl_tcp.crlf);
   utl_smtp.write_raw_data(v_conn,
               utl_raw.cast_to_raw(convert(p_message,
                             'zhs16gbk'))); --这样写标题和内容都能用中文
  end if;
  utl_smtp.close_data(v_conn); --关闭流
  utl_smtp.quit(v_conn); --关闭连接
 exception
  when others then
   dbms_output.put_line(dbms_utility.format_error_stack);
   dbms_output.put_line(dbms_utility.format_call_stack);
 end;

如对本文有疑问,请在下面进行留言讨论,广大热心网友会与你互动!! 点击进行留言回复

相关文章:

验证码:
Copyright © 2020  萬仟网 保留所有权利. 粤ICP备17035492号-1
站长QQ:2386932994 | 联系邮箱:2386932994@qq.com